home contribute faq download

FunctX XSLT Functions

functx:update-attributes

Updates the attribute value of an XML element

Google
Webxsltfunctions.com

Description

The functx:update-attributes function takes one or more XML element nodes, along with a sequence of attribute names and a sequence of attribute values, and returns a newly constructed element with those attributes updated. The attribute names and values are positionally related, i.e. the first attribute name corresponds to the first attribute value, the second name to the second value, etc. It leaves all the original attributes and content of the element, except that if it already has an attribute with the same name of one of $attrNames, its value is updated to match the corresponding value in $attrValues. Unlike the functx:add-or-update-attributes function, if the attribute did not previous exist on the element, it is not added.

Each name must be specified as an xs:QName value. QNames can be constructed with calls to the xs:QName type constructor or the fn:QName function, as shown in the examples.

The functx:update-attributes function takes one or more XML element nodes, along with an attribute name and value, and returns a newly constructed element with that attribute's value updated (and all the same content and attributes that existed on the original element.) If the attribute did not previous exist on the element, it is not added.

Arguments and Return Type

NameTypeDescription
$elements element()* the element(s) for which you wish to update the attribute
$attrNames xs:QName* the name(s) of the attribute(s) to add
$attrValues xs:anyAtomicType* the value(s) of the attribute(s) to add
return value element()?

XSLT Function Declaration

See XQuery definition.
<xsl:function name="functx:update-attributes" as="element()?"
              xmlns:functx="http://www.functx.com">
  <xsl:param name="elements" as="element()*"/>
  <xsl:param name="attrNames" as="xs:QName*"/>
  <xsl:param name="attrValues" as="xs:anyAtomicType*"/>

  <xsl:for-each select="$elements">
    <xsl:variable name="element" select="."/>
    <xsl:copy>
      <xsl:for-each select="$attrNames">
        <xsl:variable name="seq" select="position()"/>
        <xsl:if test="$element/@*[node-name(.) = current()]">
          <xsl:attribute name="{.}"
                         namespace="{namespace-uri-from-QName(.)}"
                         select="$attrValues[$seq]"/>
        </xsl:if>
      </xsl:for-each>
      <xsl:copy-of select="@*[not(node-name(.) = $attrNames)]|node()"/>
    </xsl:copy>
  </xsl:for-each>

</xsl:function>

Examples

<xsl:variable name="in-xml" as="item()*">
<in-xml xmlns:new='http://new'>
   <a att1='def'>x</a>
   <b>x</b>
   <c new:att1='def'>x</c>
</in-xml>
</xsl:variable>
XPath ExampleResults
functx:update-attributes(
   $in-xml/a, xs:QName('att1'), 123)
<a att1="123">x</a>
functx:update-attributes(
   $in-xml/a,
   (xs:QName('att1'),xs:QName('att2')),
   (1,2))
<a att1="1">x</a>
functx:update-attributes(
   $in-xml/b, xs:QName('att1'), 123)
<b>x</b>
functx:update-attributes(
     $in-xml/c,
     QName('http://new','att1'),
     123)
<c xmlns:new="http://new" new:att1="123">x</c>

See Also

functx:add-attributesAdds attributes to XML elements
functx:copy-attributesCopies attributes from one element to another
functx:remove-attributesRemoves attributes from an XML element, based on name

History

Published OnLast UpdatedContributor(s)
2006-06-272007-08-08Priscilla Walmsley, Datypic, pwalmsley@datypic.com, http://www.datypic.com
Datypic XSLT Services

Recommended Reading:

XQuery